// *** IMAGE SOURCES ***
$puts(imgsrc,$replace(%path%,%filename_ext%,*.jpg))

// *** ALIGNMENT VARIABLES ***
$puts(imgwmax,150)
$puts(rowheight,17)
$puts(calcimgh,$mul(%_itemcount%,$get(rowheight)))
$puts(imgw,
$if($fileexists($get(imgsrc)),
$if($greater($get(calcimgh),$get(imgwmax)),$get(imgwmax),$get(calcimgh)),
0))
$puts(leftpad,$if($fileexists($get(imgsrc)),10,0))
$puts(colpad,10)
$puts(colw,20)
$puts(colwtrackno,25)
$puts(textleft,$if($greater(%_itemcount%,1),$add($add($get(leftpad),$get(imgw)),$get(colpad)),$get(colpad)))
$puts(aligntrackno,$alignabs($get(textleft),-4,$get(colwtrackno),25,center,middle))
$puts(aligntrack,$alignabs($add($get(textleft),$get(colwtrackno)),0,$sub(%_width%,$add($add($get(textleft),$get(colwtrackno)),35)),$get(rowheight),left,middle))
$puts(aligntime,)

// *** COLOUR & FONT SETTINGS ***
$puts(font,calibri)
$puts(fontSize,8)
$puts(fontSizeSelected,10)
$puts(fontColor,150-150-150)
$puts(fontSmall,Small Fonts)
$puts(fontSmallSize,7)
$puts(fontSmallColor,255-255-255)
$puts(fontLength,Silkscreen)
$puts(fontLengthSize,6)
$puts(fontLengthColor,111-111-111)

// *** HOTNESS CODE ***
$puts(hotness,
$if(%play_count%,
$if($greater(%play_count%,1),
$if($greater(%play_count%,2),
$if($greater(%play_count%,3),
$if($greater(%play_count%,9),
253-78-21
,183-78-21)
,164-115-62)
,163-124-82)
,153-140-120)
,150-150-150)
)

// *** ALBUM ART DISPLAY & PNG OVERLAY ***
$if($and($fileexists($get(imgsrc)),$greater(%_itemcount%,1)),
$imageabs2($get(imgw),$get(imgw),,$mul($get(rowheight),$sub(%tracknumber%,1)),$get(imgw),$get(rowheight),$get(leftpad),,$get(imgsrc),NOKEEPASPECT)
$imageabs2($get(imgw),$get(imgw),,$mul($get(rowheight),$sub(%tracknumber%,1)),$get(imgw),$get(rowheight),$get(leftpad),,'C:/Documents and Settings/FofR/Application Data/foobar2000/images/artoverlay-1.png',NOKEEPASPECT)
)

// *** ALTERNATE ROW COLOURS ***
$if($greater($mod(%list_index%,2),0),
$drawrect($get(textleft),0,$sub(%_width%,$add($get(textleft),10)),0,brushcolor-10-10-10 pencolor-10-10-10),)

// *** DRAW SELECTED, PLAYING AND FOCUSED BOXES ***
$if($or(%_selected%,%isplaying%),$drawrect($get(textleft),0,$sub(%_width%,$add($get(textleft),10)),0,brushcolor-20-20-20 pencolor-null))
$if(%_focused%,$drawrect($get(textleft),0,$sub(%_width%,$add($get(textleft),10)),0,brushcolor-null pencolor-80-80-80))
$if(%isplaying%,$drawrect($get(textleft),0,$sub(%_width%,$add($get(textleft),10)),0,brushcolor-null pencolor-164-109-52))
$if($or(%_selected%,%isplaying%),$textcolor(SYSCOL-9),$textcolor(SYSCOL-8))

// *** TRACK NO. COL ***
$if($or(%_selected%,%isplaying%),,
$get(aligntrackno)
$font($get(fontLength),$get(fontLengthSize),fixedwidth,$get(fontSmallColor))
%tracknumber%)

// *** PROGRESS BAR ***
$if(%isplaying%,
$padding($add($get(textleft),8),0)
$puts(progress,$muldiv(%playback_time_seconds%,$sub(%_width%,$add($get(textleft),10)),%length_seconds%))
$ifgreater($get(progress),0,
$drawrect(-7,1,$get(progress),15,brushcolor-85-44-40 pencolor-null),)
)

// *** NORMAL PLAYLIST ***
// Determine if Various Artists album based on filename (VA, OST, DJ Kicks)
$if($or($strstr(%path%,'VA'),$strstr(%path%,'Incompletes'),$strstr(%path%,'OST'),$strstr(%path%,'DJ Kicks'),$strstr(%cwb_activelist%,Search)),

// *** VARIOUS ALBUMS ***
$if($or(%_selected%,%isplaying%),
$get(aligntrack)
$font($get(font),$get(fontSizeSelected),bold,200-200-200)%artist% - $font($get(font),$get(fontSizeSelected),bold,255-255-255)%title%
,
// When Not Selected
$get(aligntrack)
$font($get(fontSmall),$get(fontSmallSize),,$get(fontSmallColor))%artist% 
$font(,,,$get(hotness))
  %title%
),

// *** NORMAL ALBUMS ***
$get(aligntrack)
$font($get(font),
$if($or(%_selected%,%isplaying%),$get(fontSizeSelected),$get(fontSize)),$if($or(%_selected%,%isplaying%),bold),$if($or(%_selected%,%isplaying%),255-255-255,$get(hotness)))
$if($or(%_selected%,%isplaying%),$font($get(font),$get(fontSizeSelected),bold,200-200-200)%artist% - $font($get(font),$get(fontSizeSelected),bold,255-255-255))%title%

//End of VA IF
)

// *** TRACK LENGTH COL ***
$font($get(fontLength),$get(fontLengthSize),fixedwidth,$get(fontLengthColor))
$if($or(%_selected%,%isplaying%),$alignabs($sub(%_width%,33),4,100,20,left,top)$font(,,fixedwidth,$get(fontLengthlColor))[%playback_time_remaining%],$alignabs($sub(%_width%,33),4,100,20,left,top)$font(,,fixedwidth,$get(fontSmallColor))%length%)

// *** ICONS CODE ***
// Now playing image
$if($and(%isplaying%,$not(%RATING%)),
$imageabs2($add($mul($get(textleft),2),24),,,,,,,,C:\Documents and Settings\FofR\Application Data\foobar2000\images\speaker-1.png,NOKEEPASPECT)
)
// Ratings images
$if(%RATING%,  
$if($greater(%RATING%,4),
// If Rating > 4 show HEART image
$imageabs2($add($mul($get(textleft),2),24),,,,,,,,C:\Documents and Settings\FofR\Application Data\foobar2000\images\heart-1.png,NOKEEPASPECT) ,
// Else show STAR
$imageabs2($add($mul($get(textleft),2),24),,,,,,,,C:\Documents and Settings\FofR\Application Data\foobar2000\images\star3.png,NOKEEPASPECT)))